A lesser-known fact is that it has a command line interface.

$ say "hello world"

This CLI offers some useful options, like specifying a voice and saving to file. By pairing this with LaunchBar, we can build actions that take text input and instantly generate a spoken audio file. I’ve been using this to add spoken audio files to my Anki flashcards:

I used to go to Forvo to get audio spoken by actual humans, but there were too many downsides to this. The audio quality, volume, and accents are inconsistent, and it gets pretty tedious when you’re making lots of new flashcards each day. I also find it more effective to have my audio files include articles when learning gendered nouns. And sometimes, you just want to learn a specific phrase that isn’t available on Forvo.

The built-in speech synthesis CLI + LaunchBar combo is the perfect solution for this.

Download on GitHub

Update (Sep 10, 2020) — A more feature-packed polyglot version of this script, as well as my other LaunchBar actions, are now available on GitHub. The rest of this page may be out of date.

How to set up

First, go to System Preferences ▸ Accessibility ▸ Speech, and make sure you’ve installed the voice you want to use.

Next, here’s the AppleScript we’ll be using as the LaunchBar action. The way I have it set up, the text is spoken by the voice chosen in the Accessibility settings, and the audio is saved as an .m4a file in my system’s temporary folder (so as not to clutter my desktop). You should alter this script to meet your exact needs. For example, you might want to add a voice argument to the shell script (e.g. -v alex) to specify a certain voice.

on handle_string(str)
	
	set timeStr to (time of (current date))
	set tempItemsPath to POSIX path of (path to temporary items)
	set filePath to tempItemsPath & timeStr & ".m4a"
	set output to do shell script "say " & quoted form of str & " --data-format=aac -o " & filePath
	
	tell application "LaunchBar"
		set selection to filePath
		activate
	end tell
	
end handle_string

Aug 2, 2020: Updated for macOS Catalina

Place the .scpt file in your LaunchBar actions folder: ~/Library/Application Support/LaunchBar/Actions/

That’s it!

このところアマゾンからの荷物がTMG便／デリバリープロバイダ／PHYZ (ファイズ) という、正式名称もはっきりしない配送業者から来ることが増えてきた。この業者、ウェブサイトにアマゾン客専用の照会・再配達ページがあるにも関わらず、実際に追跡番号を入力してみると「お問い合わせ情報が存在しません」と表示されるだけで、登録されていたためしがない。2016年にもなって、わざわざ電話をかけないと再配達の依頼もできない。

私は自動受付電話が肉声電話の次に嫌いなので、少しでも心労を和らげようと Mac の iPhone通話機能を利用して半自動的に再配達電話をかける AppleScript を書いてしばらく使っている。

表示されるダイアログに追跡番号をコピペして、希望日時を選択すると、iPhone経由で自動的に発信して数字を全部入力してくれる。最後に音声案内が依頼内容をまとめて復唱して「よろしければ1を…」みたいに言ってくるので、それを一応確認して自分でキーパッドの “1” を押して終わりという感じ。気づかない間に電話システムが変わってたりしたら困るから最後の確認だけ手動にしてるけど、無鉄砲な人はここの段まで自動化しちゃっていいと思う。

ウェブ版も作ってみた

【2017年2月8日 追記】Googleのページランクが想定外に高くなってしまい、なんか申し訳ないのでAppleScriptを使わずにウェブから電話をかけられるのも作りました。電話発信リンクに対応したスマートフォンやパソコンから使えます。

AppleScript版

-- 指定した内容でTMG便に再配達依頼の電話をかける。最後に依頼内容を復唱されるのでそのときに"1"を押して終わり。
-- 2017年2月8日 更新
property dialog_title : "TMG便 - 再配達依頼"
property phone_no : "050-5525-7445"
property my_days : {"当日", "翌日"}
property my_timeslots : {"9〜12時", "12〜14時", "14〜16時", "16〜18時", "18〜20時", "20〜21時", "指定時間なし"}

tell application "System Events"
	activate
	
	-- 追跡番号
	set track_no to text returned of (display dialog "追跡番号" default answer "" with title dialog_title)
	
	if (count of track_no) is not 12 then
		display alert dialog_title message "追跡番号が12桁ではありません"
		error number -128 -- exit
	end if
	
	-- 希望日
	set my_day_response to (choose from list my_days with title dialog_title with prompt "希望日:" default items (item 1 of my_days))
	if my_day_response is false then error number -128 -- exit
	set my_day_code to my getIndexInArray((item 1 of my_day_response), my_days)
	
	-- 希望時間
	set my_timeslot_response to (choose from list my_timeslots with title dialog_title with prompt "※ 受付時間" & return & "9〜18時は当日9時まで" & return & "18〜21時は当日18時まで" & return & return & "希望時間:" default items (item 1 of my_timeslots))
	if my_timeslot_response is false then error number -128 -- exit
	set my_timeslot_code to my getIndexInArray((item 1 of my_timeslot_response), my_timeslots)
	
	-- 確認
	display dialog "【追跡番号】" & track_no & return & "【希望日時】" & (item 1 of my_day_response) & " " & (item 1 of my_timeslot_response) & return & return & "この内容で発信しますか？" with title dialog_title
	
	-- 現在時刻を元に調整
	set current_time to time of (current date)
	if current_time > (18 * 3600) then -- past 18:00
		set day_string to ""
	else
		set day_string to my_day_code & ",,,1,,,"
	end if
	
	-- 発信
	open location "tel:" & phone_no & ",,,,,," & track_no & "#,,,,,,,1" & ",,," & day_string & my_timeslot_code & ",,,,1"
	
end tell

on getIndexInArray(my_item, my_array)
	repeat with i from 1 to the count of my_array
		if item i of my_array is my_item then return i
	end repeat
	return 0
end getIndexInArray

TMGサイトの一時的なトラブルかと思って我慢していたけど、何ヶ月経っても直らないので早く直してほしい。

This allows you to have a single keyboard shortcut that works as a normal “previous track” key when listening to music, but automatically switches to a 30-second rewind when listening to podcasts, audiobooks, or whatever else you specify.

property skip_secs : 30 -- use negative value to rewind, positive value to skip ahead
property genre_list : {"Podcast", "Books & Spoken"}

tell application "iTunes"
	if (exists of current track) is false then
		return
	end if
	
	if genre of current track is in genre_list then
		set target_time to (player position + skip_secs)
		
		if (target_time > finish of current track) then
			next track
		else if (target_time < 2) then
			back track
		else
			set player position to target_time
		end if
		
	else -- rewind/skip the whole track
		if (skip_secs < 0) then
			back track
		else
			next track
		end if
	end if
end tell

Options

Change the skip_secs property to your preferred interval in seconds. For example, setting skip_secs to 30 will result in a 30-sec fast forward, while setting it to -15 will make it a 15-sec rewind.

If you would like more kinds of tracks to respond to this skip behavior, add the genre names of those tracks to genre_list.

例えば Typinator でブラケット [] の auto-pairing を普通に設定すると、日本語モードでカギ括弧を打ってるときにまで自動補完してきて困る。そういうときに入力モードの判定スクリプトを挟むと、英語モードのときだけ自動補完してくれるように設定可能。

property true_if_input : "U.S." -- input mode name to test for

tell application "System Events"
	tell process "SystemUIServer"
		set current_input to value of first menu bar item of menu bar 1 whose description is "text input"
	end tell
end tell

if current_input is true_if_input then
	return true
else
	return false
end if

※ GUIスクリプティングなので、システム環境設定 ＞ ユニバーサルアクセス ＞ 補助装置にアクセスできるようにする がオンになっている必要がある

property resolution : 10 (* Increase for smoother fades. Default: 10 *)
property delayIncr : 0.2 (* Decrease for faster fades. Default: 0.2 *)

tell application "iTunes"
	set originalVol to sound volume
	set volIncr to originalVol div resolution
	
	if player state is not playing then
		set sound volume to 0
		play
		
		-- Fade in
		repeat while (sound volume ≤ (originalVol - volIncr))
			set sound volume to (sound volume + volIncr)
			delay delayIncr
		end repeat
		
	else
		-- Fade out
		repeat while (sound volume > 0)
			set sound volume to (sound volume - volIncr)
			delay delayIncr
		end repeat
		
		pause
		
	end if
	
	set sound volume to originalVol
	
end tell

AirPlay 時代のエチケット。ステレオコンポのときから、ボリュームつまみをゆっくり絞ったあとに停止ボタンを押してたタイプの人用。

使い方

Spark や Quicksilver のようなツールにスクリプトを登録しておいて、ホットキーで呼び出す。たとえば F8 に設定しておくと、 F8 がフェード付きの iTunes 再生／停止キーになる。